mirrors/zsh
1
0
Fork 0
mirror of git://git.code.sf.net/p/zsh/code synced 2025-10-25 17:20:25 +02:00
Code Releases Activity

22854: replace-string-again

Browse source
This commit is contained in:
Peter Stephenson 2006-10-10 11:24:38 +00:00
parent d4d6cb5494
commit 966a330649
4 changed files with 63 additions and 35 deletions
Download patch file Download diff file Expand all files Collapse all files

38
Functions/Zle/replace-string
View file

@ -1,11 +1,11 @@
emulate -L zsh
setopt extendedglob
autoload read-from-minibuffer
autoload -U read-from-minibuffer replace-string-again
local p1="Replace: " p2=" with: "
local REPLY MATCH MBEGIN MEND curwidget=$WIDGET previous
local -a match mbegin mend
# Saving curwidget is necessary to avoid the widget name being overwritten.
local REPLY previous curwidget=$WIDGET
if (( ${+NUMERIC} )); then
(( $NUMERIC > 0 )) && previous=1
@ -20,34 +20,4 @@ read-from-minibuffer "$p1$_replace_string_src$p2" \
${previous:+$_replace_string_rep} || return 1
_replace_string_rep=$REPLY
if [[ $curwidget = *pattern* ]]; then
local rep2
# The following horror is so that an & preceded by an even
# number of backslashes is active, without stripping backslashes,
# while preceded by an odd number of backslashes is inactive,
# with one backslash being stripped. A similar logic applies
# to \digit.
local rep=$_replace_string_rep
while [[ $rep = (#b)([^\\]#)(\\\\)#(\\|)(\&|\\<->|\\\{<->\})(*) ]]; do
if [[ -n $match[3] ]]; then
# Expression is quoted, strip quotes
rep2="${match[1]}${match[2]}${match[4]}"
else
rep2+="${match[1]}${match[2]}"
if [[ $match[4] = \& ]]; then
rep2+='${MATCH}'
elif [[ $match[4] = \\\{* ]]; then
rep2+='${match['${match[4][3,-2]}']}'
else
rep2+='${match['${match[4][2,-1]}']}'
fi
fi
rep=${match[5]}
done
rep2+=$rep
LBUFFER=${LBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
RBUFFER=${RBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
else
LBUFFER=${LBUFFER//$_replace_string_src/$_replace_string_rep}
RBUFFER=${RBUFFER//$_replace_string_src/$_replace_string_rep}
fi
replace-string-again $curwidget

45
Functions/Zle/replace-string-again Normal file
View file

@ -0,0 +1,45 @@
# Back end for replace-string; can be called as a widget to repeat
# the previous replacement. _replace_string_src and _replace_string_rep
# are global.
# When called from replace-string, we need to use the widget
# name passed to decide whether to do pattern matching: the widget
# may since have been overwritten.
local MATCH MBEGIN MEND curwidget=${1:-$WIDGET}
local -a match mbegin mend
if [[ -z $_replace_string_src ]]; then
zle -M No string to replace.
fi
if [[ $curwidget = *pattern* ]]; then
local rep2
# The following horror is so that an & preceded by an even
# number of backslashes is active, without stripping backslashes,
# while preceded by an odd number of backslashes is inactive,
# with one backslash being stripped. A similar logic applies
# to \digit.
local rep=$_replace_string_rep
while [[ $rep = (#b)([^\\]#)(\\\\)#(\\|)(\&|\\<->|\\\{<->\})(*) ]]; do
if [[ -n $match[3] ]]; then
# Expression is quoted, strip quotes
rep2="${match[1]}${match[2]}${match[4]}"
else
rep2+="${match[1]}${match[2]}"
if [[ $match[4] = \& ]]; then
rep2+='${MATCH}'
elif [[ $match[4] = \\\{* ]]; then
rep2+='${match['${match[4][3,-2]}']}'
else
rep2+='${match['${match[4][2,-1]}']}'
fi
fi
rep=${match[5]}
done
rep2+=$rep
LBUFFER=${LBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
RBUFFER=${RBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
else
LBUFFER=${LBUFFER//$_replace_string_src/$_replace_string_rep}
RBUFFER=${RBUFFER//$_replace_string_src/$_replace_string_rep}
fi