mirrors/zsh
1
0
Fork 0
mirror of git://git.code.sf.net/p/zsh/code synced 2025-09-01 09:41:44 +02:00
Code Releases Activity

42981: Add ed completer

Browse source
This commit is contained in:
Matthew Martin 2018-06-15 14:12:12 -05:00
parent 9408c4825b
commit d5360e324c
2 changed files with 42 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

4
ChangeLog
View file

@ -1,3 +1,7 @@
2018-06-15 Matthew Martin <phy1729@gmail.com>
* 42981: Completion/Unix/Command/_ed: Add ed completer
2018-06-15 Peter Stephenson <p.stephenson@samsung.com>
* users/23472: Doc/Zsh/mod_system.yo, Src/Modules/system.c,

38
Completion/Unix/Command/_ed Normal file
View file

@ -0,0 +1,38 @@
#compdef ed
local -a args
args=(
'(-p --prompt)'{-p+,--prompt=}'[specify prompt]:prompt:'
'(-s --quiet --silent)'{-s,--quiet,--silent}'[suppress diagnostics]'
)
if _pick_variant gnu=GNU unix --version; then
args+=(
'(-G --traditional)'{-G,--traditional}'[run in compatibility mode]'
'(- :)'{-h,--help}'[display help]'
'(-l --loose-exit-status)'{-l,--loose-exit-status}'[exit 0 even if a command fails]'
'(-r --restricted)'{-r,--restricted}'[run in restricted mode]'
'(- :)'{-V,--version}'[display version]'
'(-v --verbose)'{-v,--verbose}'[be verbose]'
)
else
args=(-A '-*' ${args:#*\)--*})
case $OSTYPE in
dragonfly*|freebsd*|netbsd*|solaris*)
args+=(
'-x[prompt for an encryption key]'
)
;|
netbsd*)
args+=(
'-E[enable extended regular expressions]'
'-S[disable ! command]'
)
;;
esac
fi
_arguments -s -S \
$args \
':file:_files'