mirror of
git://git.code.sf.net/p/zsh/code
synced 2025-09-22 04:31:14 +02:00
28 lines
928 B
Text
28 lines
928 B
Text
# Edit the command line using your usual editor.
|
|
# Binding this to 'v' in the vi command mode map,
|
|
# autoload -Uz edit-command-line
|
|
# zle -N edit-command-line
|
|
# bindkey -M vicmd v edit-command-line
|
|
# will give ksh-like behaviour for that key,
|
|
# except that it will handle multi-line buffers properly.
|
|
|
|
() {
|
|
exec </dev/tty
|
|
|
|
# Compute the cursor's position in bytes, not characters.
|
|
setopt localoptions nomultibyte
|
|
integer byteoffset=$(( $#PREBUFFER + $#LBUFFER + 1 ))
|
|
|
|
# Open the editor, placing the cursor at the right place if we know how.
|
|
local editor=${${VISUAL:-${EDITOR:-vi}}}
|
|
case $editor in
|
|
(*vim*) ${=editor} -c "normal! ${byteoffset}go" -- $1;;
|
|
(*emacs*) ${=editor} $1 -eval "(goto-char ${byteoffset})";;
|
|
(*) ${=editor} $1;;
|
|
esac
|
|
|
|
# Replace the buffer with the editor output.
|
|
print -Rz - "$(<$1)"
|
|
} =(<<<"$PREBUFFER$BUFFER")
|
|
|
|
zle send-break # Force reload from the buffer stack
|