mirror of
git://git.code.sf.net/p/zsh/code
synced 2025-10-31 18:10:56 +01:00
83 lines
2.6 KiB
Text
83 lines
2.6 KiB
Text
#compdef chmod gchmod
|
|
|
|
local curcontext="$curcontext" state line expl ret=1 variant
|
|
local -a args privs
|
|
|
|
args=( '*: :->files' '1: :_file_modes' )
|
|
|
|
_pick_variant -r variant gnu=Free\ Soft $OSTYPE --version
|
|
case "$variant" in
|
|
gnu)
|
|
args+=(
|
|
'(-v --verbose -c --changes)'{-c,--changes}'[report changes made]'
|
|
'(-v --verbose -c --changes)'{-v,--verbose}'[output a diagnostic for every file processed]'
|
|
'(-f --silent --quiet)'{-f,--silent,--quiet}'[suppress most error messages]'
|
|
'(--no-preserve-root)--preserve-root[fail to operate recursively on /]'
|
|
"(--preserve-root)--no-preserve-root[don't treat / specially (default)]"
|
|
'(1)--reference=[copy permissions of specified file]:file:_files'
|
|
'(-R --recursive)'{-R,--recursive}'[change files and directories recursively]'
|
|
'(- : *)--help[display help information]'
|
|
'(- : *)--version[display version information]'
|
|
)
|
|
;;
|
|
*)
|
|
args+=(
|
|
'-f[suppress most error messages]'
|
|
'-R[change files and directories recursively]'
|
|
)
|
|
;|
|
|
freebsd*|dragonfly*|darwin*)
|
|
args+=(
|
|
'-v[output a diagnostic for every file processed]'
|
|
)
|
|
;|
|
|
freebsd*|netbsd*|darwin*|dragonfly*)
|
|
args+=(
|
|
'-h[operate on symlinks them self]'
|
|
)
|
|
;|
|
|
freebsd*|openbsd*|netbsd*|darwin*|dragonfly*)
|
|
args+=(
|
|
'(-H -L -P)-L[follow all symlinks]'
|
|
'(-H -L -P)-H[follow symlinks on the command line]'
|
|
'(-H -L -P)-P[do not follow symlinks (default)]'
|
|
)
|
|
;|
|
|
darwin*)
|
|
args+=(
|
|
'(1)-C[returns false if any of the named files have ACLs]'
|
|
'(1)-N[remove ACLs from specified files]'
|
|
'(1)-E[read ACL info from stdin as a sequential list of ACEs]'
|
|
'(1)-i[removes inherited bit from all entries in named files ACLs]'
|
|
'(1)-I[removes all inherited entries from named files ACLs]'
|
|
)
|
|
;;
|
|
esac
|
|
|
|
_arguments -C -s "$args[@]" && ret=0
|
|
|
|
case "$state" in
|
|
files)
|
|
if [[ -n $opt_args[--reference] ]]; then
|
|
zmodload -F zsh/stat b:zstat 2>/dev/null
|
|
typeset -i8 ref=$(zstat +mode $opt_args[--reference])
|
|
_wanted files expl file _files -g "*(-.^f${ref#??})" && ret=0
|
|
elif [[ $line[1] = [0-7]## ]]; then
|
|
_wanted files expl file _files -g "*(-.^f$line[1])" && ret=0
|
|
else
|
|
local spec who op priv
|
|
local -a specs
|
|
for spec in ${(s:,:)line[1]}; do
|
|
if [[ ${spec#*[+-=]} != [rwxst]## ]]; then
|
|
_files && ret=0
|
|
return ret
|
|
fi
|
|
|
|
specs+=( ${${(M)spec##[+-=]*}:+a}$spec )
|
|
done
|
|
_wanted files expl file _files -g "*(-.^f:${(j.,.)specs}:)" && ret=0
|
|
fi
|
|
;;
|
|
esac
|
|
|
|
return ret
|