mirror of
git://git.code.sf.net/p/zsh/code
synced 2025-01-17 10:20:55 +01:00
37 lines
1,001 B
Text
37 lines
1,001 B
Text
#compdef man apropos whatis
|
|
|
|
setopt localoptions rcexpandparam
|
|
|
|
local rep expl star approx
|
|
|
|
if [[ $compstate[pattern_match] != [^*] ]]; then
|
|
# If a string other than *, we just want correction, so no `*'.
|
|
star='*'
|
|
fi
|
|
|
|
if [[ -n $_comp_correct ]]; then
|
|
# If this is set, we are correcting with this many approximations.
|
|
approx="(#a${_comp_correct})"
|
|
fi
|
|
|
|
if (( ! $#manpath )); then
|
|
local mp
|
|
mp=($(manpath 2>/dev/null))
|
|
[[ "$mp" == *:* ]] && mp=( ${(s.:.)mp} )
|
|
manpath=( $mp )
|
|
fi
|
|
|
|
(( $#manpath )) || manpath=( ${(s.:.)$(manpath 2>/dev/null)} ) ||
|
|
manpath=( /usr/man(-/N) /(opt|usr)/(dt|share|X11R6|local)/(cat|)man(-/N) )
|
|
|
|
# `sman' is the SGML manual directory for Solaris 7.
|
|
|
|
if [[ $words[2] = (<->*|l|n) ]]; then
|
|
rep=(
|
|
$manpath/(sman|man|cat)${words[2]}/${~approx}$PREFIX${~star}$SUFFIX.<->*(N:t) )
|
|
else
|
|
rep=( $manpath/(sman|man|cat)*/${~approx}$PREFIX${~star}$SUFFIX.<->*(N:t) )
|
|
fi
|
|
|
|
(( $#rep )) && _wanted manuals expl 'manual page' \
|
|
compadd - ${rep%%.[^.]##(.gz|.bz2|)}
|